Calculer les dates des jours fériés automatiquement sous Excel

(Last Updated On: 18 octobre 2017)

Que ce soit pour la mise à jour de planning sous Excel, le calcul de la durée de projets, etc… connaître les jours fériés de l’année est essentiel pour toute entreprise !  Mais le problème avec les jours fériés, c’est que certains n’ont pas de date fixe dans le calendrier, la date variant d’une année à l’autre.

La solution souvent utilisée et la plus simple est de prendre son agenda ou son calendrier et de rentrer en dur les dates dans son fichier Excel. Mais si j’ai besoin des dates sur plusieurs années, l’affaire peut rapidement devenir fastidieuse… Alors n’y a-t-il pas un moyen de calculer automatiquement les dates des jours fériés d’une année ?

Voici un article présentant des formules pour calculer les dates des jours fériés en France automatiquement en fonction de l’année considérée.

A noter que la date du jour de Pâques peut varier selon l’année, c’est la plus compliquée à obtenir. La formule présentée ici provient de recherches internet menant à cette newsgroup.

D’autres dates de fêtes religieuses sont aussi mobiles mais ont comme point de référence le jour de Pâques.

Les autres dates des jours fériés sont faciles à obtenir car elles sont fixes.

  1. Insérez l’année, par exemple 2017, en cellule C3 dans une feuille Excel
  2. Copier-coller les formules ci-dessous (en partant de la cellule D6) pour obtenir les dates des jours fériés :
Jour de l’an = DATE($C$3;1;1)
Pâques (cellule D7) = PLANCHER(JOUR(MINUTE($C$3/38)/2+56)&"/5/"&$C$3;7)-34
Lundi de Pâques = D7 + 1
Fête du travail = DATE($C$3;5;1)
Armistice 39/45 = DATE($C$3;5;8)
Ascension = D7 + 39
Pentecôte = D7 + 49
Lundi de Pentecôte = D7 + 50
Fête Nationale = DATE($C$3;7;14)
Assomption = DATE($C$3;8;15)
Toussaint = DATE($C$3;11;1)
Armistice 14/18 = DATE($C$3;11;11)
Noël = DATE($C$3;12;25)

Vous devriez obtenir le résultat suivant pour l’année 2017 :

Application au calcul du nombre de jours ouvrés

Une application directe est le calcul du nombre de jours ouvrés entre deux dates, en tenant compte du nombre de jours fériés entre ces deux dates.

Excel propose une formule pour cela : NB.JOURS.OUVRES(date_début;date_fin;[jours_fériés])

jours_fériés représente une plage facultative d’une ou de plusieurs dates à exclure du calendrier des jours ouvrés.

  1. Transformer la table des jours fériés précédemment créée en Tableau Excel. Nommez votre tableau « Jours_fériés »
  2. Insérer en H5 la date de début, et en H6 la date de fin
  3. Insérer la formule suivante en H7 : =NB.JOURS.OUVRES(H5;H6;Jours_fériés[Formules], où [Formules] représente la colonne des dates des jours fériés à exclure du calcul

Vous pouvez tester si votre formule fonctionne avec les données suivantes. Si tout va bien, vous devriez obtenir le même nombre de jours ouvrés.

TELECHARGER LE FICHIER D’EXEMPLE

Télécharger le classeur Excel pour ce tutoriel. Seuls votre adresse e-mail et nom vous seront demandés dans la prochaine étape. Vous recevrez le lien de téléchargement par e-mail.

 

13 commentaires

    • Lionel dit

      Bonjour,

      Oui vous avez raison ! Bien que dans le projet qui m’a inspiré cet article, il y avait une raison à considérer le 1er janvier comme jour férié de l’année suivante, mais je ne m’en rappelle plus :-/

      Quoi qu’il en soit j’ai corrigé la formule.

      Merci pour votre commentaire
      Lionel

  1. Ienien dit

    Bonjour,

    La formule ne fonctionne pas pour le jour Férié de Pâques pour les année 2018-2019-2020.
    Même chose pour une autre formule trouvée sur un autre site.

    Cordialement

  2. Ienien dit

    RE bonjour,

    Je suis tombé sur une formule tombant juste pour les fériés 2018-2019-2020. la voici : =DATE(année;3;29,56+0,979*MOD(204-11*MOD(année;19);30)-JOURSEM(DATE(année;3;28,56+0,979*MOD(204-11*MOD(année;19);30)))).

    En revanche : pour l’ascension il faut ajouter 39 et pentecote : +50

    • Lionel dit

      Bonjour,

      Merci pour votre commentaire et votre formule alternative pour Pâques.
      Les deux formules donnent les mêmes résultats pour dimanche de Pâques :
      2017 : 16/04/2017
      2018 : 01/04/2018
      2019 : 21/04/2019
      2020 : 12/04/2020

      J’ai également vérifié les dates calculées avec celles données dans ce site et elles concordent bien jusqu’à au moins 2027 : https://www.calendrier-365.fr/jours-feries/lundi-de-paques.html

      Pour obtenir les dates de l’Ascension et la Pentecôte : il faut bien ajouter 39 et 49 au dimanche de Pâques.

      Quelle était votre source pour obtenir la date de Pâques ?

      Lionel

      • Branchereau dit

        Bonjour,

        je dirais même que la formule est exact jusqu’à 2079 pour la première erreur.
        la deuxième occurrence survient en 2204, puis plus fréquemment ensuite.
        Et au bout d’un millénaire, il y aura un décalage tous les ans à peu près.

        Mais à l’échelle de nos vies, on peut se contenter de cette formule là.

        Pour les plus tatillon, il faudrait utiliser la méthode de Meeus.
        J’ai pour ma part mis l’intégralité de la formule dans une seule cellule (qui est imbuvable).
        =DATE(année;QUOTIENT(MOD(19*MOD(année;19)+QUOTIENT(année;100)-QUOTIENT(QUOTIENT(année;100);4)-QUOTIENT(QUOTIENT(année;100)-QUOTIENT(QUOTIENT(année;100)+8;25)+1;3)+15;30)+MOD(2*MOD(QUOTIENT(année;100);4)+2*QUOTIENT(MOD(année;100);4)-MOD(19*MOD(année;19)+QUOTIENT(année;100)-QUOTIENT(QUOTIENT(année;100);4)-QUOTIENT(QUOTIENT(année;100)-QUOTIENT(QUOTIENT(année;100)+8;25)+1;3)+15;30)-MOD(MOD(année;100);4)+32;7)-7*QUOTIENT(MOD(année;19)+11*MOD(19*MOD(année;19)+QUOTIENT(année;100)-QUOTIENT(QUOTIENT(année;100);4)-QUOTIENT(QUOTIENT(année;100)-QUOTIENT(QUOTIENT(année;100)+8;25)+1;3)+15;30)+22*MOD(2*MOD(QUOTIENT(année;100);4)+2*QUOTIENT(MOD(année;100);4)-MOD(19*MOD(année;19)+QUOTIENT(année;100)-QUOTIENT(QUOTIENT(année;100);4)-QUOTIENT(QUOTIENT(année;100)-QUOTIENT(QUOTIENT(année;100)+8;25)+1;3)+15;30)-MOD(MOD(année;100);4)+32;7);451)+114;31);MOD(MOD(19*MOD(année;19)+QUOTIENT(année;100)-QUOTIENT(QUOTIENT(année;100);4)-QUOTIENT(QUOTIENT(année;100)-QUOTIENT(QUOTIENT(année;100)+8;25)+1;3)+15;30)+MOD(2*MOD(QUOTIENT(année;100);4)+2*QUOTIENT(MOD(année;100);4)-MOD(19*MOD(année;19)+QUOTIENT(année;100)-QUOTIENT(QUOTIENT(année;100);4)-QUOTIENT(QUOTIENT(année;100)-QUOTIENT(QUOTIENT(année;100)+8;25)+1;3)+15;30)-MOD(MOD(année;100);4)+32;7)-7*QUOTIENT(MOD(année;19)+11*MOD(19*MOD(année;19)+QUOTIENT(année;100)-QUOTIENT(QUOTIENT(année;100);4)-QUOTIENT(QUOTIENT(année;100)-QUOTIENT(QUOTIENT(année;100)+8;25)+1;3)+15;30)+22*MOD(2*MOD(QUOTIENT(année;100);4)+2*QUOTIENT(MOD(année;100);4)-MOD(19*MOD(année;19)+QUOTIENT(année;100)-QUOTIENT(QUOTIENT(année;100);4)-QUOTIENT(QUOTIENT(année;100)-QUOTIENT(QUOTIENT(année;100)+8;25)+1;3)+15;30)-MOD(MOD(année;100);4)+32;7);451)+114;31)+1)

        Cordialement

        Fabien

  3. Ray dit

    Bonjour,

    Bizarre ..super formule et bien utile mais petit problème. En recopiant exactement votre formule dans ma feuille .. le calcul pour Pâques et Pentecôte, est décalé d’un jour !?
    Uen ideé?

    merci

    • Lionel dit

      Bonjour,

      Merci pour votre commentaire.
      Ca dépend si vous regardez le dimanche ou le lundi ?
      La formule pour Pâques calcule la date de la fête qui est un dimanche, il faut ajouter +1 pour avoir le jour férié du lundi, idem pour la Pentecôte.
      C’est pour cela que dans le tableau dans l’article je précise le jour de la fête et le lundi férié associé.

      Lionel

  4. Ray dit

    Bonjour et merci de votre réponse ,
    nous ne sommes pas bien compris j’ai bien vu la différence entre le lundi de pâque et pâque. Pour une raison que j’ignore , probablement liée a ma config (?) entre votre classeur et le mien sur le même PC , copié a l’identique, les fériés flottants sont complètement erronés.
    2018 : Paques 7/04 au lieu de 1/04
    Lundi de paque 8/0 au lieu de 2/04

    Surement un truc énorme qui m’échappe!

  5. Ray dit

    Pour les autres pouvant galérer sur le meme problème .. attention au fichier provenant d’un MAC !!

    « … À la fois Excel pour Mac et Excel pour Windows prend en charge les systèmes de date 1900 et 1904. Le système de date par défaut pour Excel pour Windows est 1900 ; et le système de date par défaut pour Excel pour Mac est basé sur 1904. … »

Laisser un commentaire

Votre adresse de messagerie ne sera pas publiée. Les champs obligatoires sont indiqués avec *